gentoo/dev-db/influxdb/influxdb-1.7.9.ebuild

# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

EGO_PN="github.com/influxdata/${PN}"
EGO_VENDOR=(
	"github.com/influxdata/flux v0.50.2" # MIT
	"github.com/influxdata/influxql v1.0.1" # MIT
	"github.com/influxdata/line-protocol a3afd890113fb9f0337e05808bb06fb0ca4c685a" # MIT
	"github.com/influxdata/tdigest bf2b5ad3c0a925c44a0d2842c5d8182113cd248e" # Apache-2.0
	"github.com/influxdata/roaring fc520f41fab6dcece280e8d4853d87a09a67f9e0" # Apache-2.0
	"github.com/influxdata/usage-client 6d3895376368aa52a3a81d2a16e90f0f52371967" # MIT
	"github.com/gogo/protobuf v1.1.1"  # license: BSD
	"cloud.google.com/go v0.47.0 github.com/googleapis/google-cloud-go" # Apache-2.0
	"github.com/apache/arrow af6fa24be0dbbc021e0844c63d1c0b89fb23a95c" # Apache-2.0
	"github.com/c-bata/go-prompt v0.2.1" # MIT
	"github.com/cespare/xxhash v1.0.0" # MIT
	"github.com/eclipse/paho.mqtt.golang v1.2.0" # EPL-1.0
	"github.com/go-sql-driver/mysql v1.4.1" # MPL-2.0
	"github.com/golang/protobuf v1.1.0" # BSD
	"github.com/golang/snappy d9eb7a3d35ec988b8585d4a0068e462c27d28380" # BSD
	"github.com/google/go-cmp v0.2.0" # BSD
	"github.com/googleapis/gax-go v2.0.5" # BSD
	"github.com/jsternberg/zap-logfmt v1.0.0" # MIT
	"github.com/lib/pq v1.0.0" # MIT
	"github.com/mattn/go-isatty 6ca4dbf54d38eea1a992b3c722a76a5d1c4cb25c" # MIT
	"github.com/matttproud/golang_protobuf_extensions v1.0.1" # Apache-2.0
	"github.com/opentracing/opentracing-go bd9c3193394760d98b2fa6ebb2291f0cd1d06a7d" # Apache-2.0
	"github.com/peterh/liner 8c1271fcf47f341a9e6771872262870e1ad7650c" # MIT-with-advertising
	"github.com/mattn/go-runewidth v0.0.2" # MIT
	"github.com/pkg/errors v0.8.0" # BSD-2
	"github.com/pkg/term bffc007b7fd5a70e20e28f5b7649bb84671ef436" # BSD-2
	"github.com/prometheus/common 7600349dcfe1abd18d72d3a1770870d9800a7801" # Apache-2.0
	"github.com/prometheus/client_golang 661e31bf844dfca9aeba15f27ea8aa0d485ad212" # Apache-2.0
	"github.com/prometheus/client_model 5c3871d89910bfb32f5fcab2aa4b9ec68e65a99f" # Apache-2.0
	"github.com/prometheus/procfs ae68e2d4c00fed4943b5f6698d504a5fe083da8a" # Apache-2.0
	"github.com/beorn7/perks 3a771d992973f24aa725d07868b467d1ddfceafb" # MIT
	"github.com/satori/go.uuid v1.2.0" # MIT
	"github.com/segmentio/kafka-go v0.2.2" # MIT
	"github.com/xlab/treeprint d6fb6747feb6e7cfdc44682a024bddf87ef07ec2" # MIT-with-advertising
	"go.opencensus.io v0.22.1 github.com/census-instrumentation/opencensus-go" # Apache-2.0
	"github.com/golang/groupcache 404acd9df4cc9859d64fb9eed42e5c026187287a" # Apache-2.0
	"go.uber.org/zap v1.9.0 github.com/uber-go/zap" # MIT
	"go.uber.org/atomic v1.3.2 github.com/uber-go/atomic" # MIT
	"go.uber.org/multierr v1.1.0 github.com/uber-go/multierr" # MIT
	"golang.org/x/crypto a2144134853fc9a27a7b1e3eb4f19f1a76df13c9 github.com/golang/crypto" # BSD
	"golang.org/x/net a680a1efc54dd51c040b3b5ce4939ea3cf2ea0d1 github.com/golang/net" # BSD
	"golang.org/x/sys ac767d655b305d4e9612f5f6e33120b9176c4ad4 github.com/golang/sys" # BSD
	"golang.org/x/oauth2 c57b0facaced709681d9f90397429b9430a74754 github.com/golang/oauth2" # BSD
	"golang.org/x/text v0.3.0 github.com/golang/text" # BSD
	"golang.org/x/sync 1d60e4601c6fd243af51cc01ddf169918a5407ca github.com/golang/sync" # BSD
	"golang.org/x/time fbb02b2291d28baffd63558aa44b4b56f178d650 github.com/golang/time" # BSD
	"google.golang.org/api v0.5.0 github.com/googleapis/google-api-go-client" # BSD MIT
	"google.golang.org/genproto fedd2861243fd1a8152376292b921b394c7bef7e github.com/google/go-genproto" # Apache-2.0
	"google.golang.org/grpc v1.13.0 github.com/grpc/grpc-go" # Apache-2.0
	"github.com/dgryski/go-bitstream 3522498ce2c8ea06df73e55df58edfbfb33cfdd6" # MIT
	"github.com/glycerine/go-unsnap-stream 9f0cb55181dd3a0a4c168d3dbc72d4aca4853126" # MIT-with-advertising
	"github.com/jwilder/encoding b4e1701a28efcc637d9afcca7d38e495fe909a09" # MIT
	"github.com/retailnext/hllpp 101a6d2f8b52abfc409ac188958e7e7be0116331" # BSD
	"github.com/tinylib/msgp v1.0.2" # MIT
	"github.com/philhofer/fwd v1.0.0" # MIT
	"github.com/BurntSushi/toml a368813c5e648fee92e5f6c30e3944ff9d5e8895" # MIT
	"collectd.org v0.3.0 github.com/collectd/go-collectd" # ISC
	"github.com/bmizerany/pat 6226ea591a40176dd3ff9cd8eff81ed6ca721a00" # MIT-with-advertising
	"github.com/dgrijalva/jwt-go v3.2.0" # MIT
	"github.com/spf13/cast v1.3.0" # MIT
	"github.com/boltdb/bolt v1.3.1" # MIT
	"github.com/klauspost/pgzip v1.1" # MIT
	"github.com/klauspost/compress v1.4.0" # BSD
	"github.com/klauspost/cpuid v1.1" # MIT
	"github.com/klauspost/crc32 v1.1" # BSD
	"github.com/paulbellamy/ratecounter v0.2.0" # MIT
)
EGIT_COMMIT="23bc63d"
EGIT_BRANCH="master"

inherit go-module systemd user

DESCRIPTION="Scalable datastore for metrics, events, and real-time analytics"
HOMEPAGE="https://www.influxdata.com"
SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
	$(go-module_vendor_uris)"

LICENSE="MIT BSD Apache-2.0 EPL-1.0 MPL-2.0 MIT-with-advertising BSD-2 ISC"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc"

DEPEND="doc? (
	>=app-text/asciidoc-8.6.10
	app-text/xmlto
)"

pkg_setup() {
	enewgroup influxdb
	enewuser influxdb -1 -1 /var/lib/influxdb influxdb
}

src_compile() {
	set -- env GOPATH="${S}" go install -a -installsuffix cgo \
		-ldflags="-s -X main.version=${PV} -X main.branch=${EGIT_BRANCH} -X main.commit=${EGIT_COMMIT}" \
		-v -work -x ./...
	echo "$@"
	"$@" || die "compile failed"
	use doc && cd man && emake build
}

src_install() {
	dobin "${S}"/bin/influx*

	use doc && dodoc *.md
	use doc && doman man/*.1

	insinto /etc/logrotate.d
	newins scripts/logrotate influxdb

	systemd_dounit scripts/influxdb.service

	newconfd "${FILESDIR}"/influxdb.confd influxdb
	newinitd "${FILESDIR}"/influxdb.rc influxdb
	insinto /etc/influxdb
	newins etc/config.sample.toml influxdb.conf
	keepdir /var/log/influxdb
	fowners influxdb:influxdb /var/log/influxdb
}