[dev-db/timescaledb] bump

dev-db/timescaledb/Manifest

@@ -1 +1 @@
-DIST timescaledb-1.6.0.tar.lzma 775863 BLAKE2B 85087a34a422f66db838444696af34f8c7211e61675a03cb57934eb3df2e42dec061fe81e42f1887e7b60681d3a5ec9a30a621027448d5b8228ae4f20fe8221d SHA512 97dafeff52b204e88abe529815e7f09f667d1726b9a3707e5f99773e92d9d0ac0982d5c176bd3fb4c0e5217a4c77489a2c88e05e4142507921bcaa13504ca8de
+DIST timescaledb-1.7.0.tar.lzma 829836 BLAKE2B c15f8b1cd3531abe2760c01d70de2c065a21f1b1650ac239cdb0a1f04ac6dc02acd60689db957fda4a9ef880a8c14bfc208cc9cf193f6808fd2ff0e729401441 SHA512 5a91a2ef600273047a29f8599dac15c985f63b53c545169f58c876b921abf7bdc5eb5dd8a59976545963b8cf286a8015014d147f7bfadfb98f9ee0539ebf0aca

dev-db/timescaledb/timescaledb-1.7.0.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+POSTGRES_COMPAT=( 9.6 {10..12} )
+POSTGRES_USEDEP="server,ssl?"
+
+inherit cmake postgres-multi
+
+DESCRIPTION="A time-series database optimized for fast ingest and complex queries"
+HOMEPAGE="https://www.timescale.com/"
+SRC_URI="https://github.com/timescale/${PN}/releases/download/${PV}/${P}.tar.lzma"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="ssl static-libs"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+BUILD_DIR="${S}"
+
+src_prepare() {
+	default
+
+	postgres-multi_src_prepare
+	postgres-multi_foreach cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_OPENSSL=$(usex ssl ON OFF)
+		-DSEND_TELEMETRY_DEFAULT=OFF
+		-DREGRESS_CHECKS=OFF
+	)
+	postgres-multi_foreach cmake_src_configure
+}
+
+src_compile() {
+	postgres-multi_foreach cmake_src_compile
+}
+
+src_install() {
+	postgres-multi_foreach cmake_src_install
+
+	use static-libs || find "${ED}" -name '*.a' -delete
+}