[net-mail/automx2] resurrect as py3k13 only package ( + deps ) for now

dev-python/flask-migrate/Manifest

@@ -0,0 +1 @@
+DIST Flask-Migrate-4.1.0.gh.tar.gz 27430 BLAKE2B 7adc49eb0b80cc74cc381ab803ccd2dfcc107beeb5fd06f24ca36a98f6e617e6f56a48c0ef739d41770ec508d4bf0e13b78f57be62d23317c8d797bfa1ef5c2d SHA512 683842e3e5832cf3eaf6b7ee5e194c1eb2fe1b096d3360a64f2f0de5024e1fa4ebd8e0b6659a1c87ded47efd0e07cecf9d82807e1e64af99a18bb9b596261963

dev-python/flask-migrate/flask-migrate-4.1.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_13 )
+
+inherit distutils-r1
+
+MY_P="Flask-Migrate-${PV}"
+DESCRIPTION="SQLAlchemy database migrations for Flask applications using Alembic"
+HOMEPAGE="
+	https://github.com/miguelgrinberg/Flask-Migrate/
+	https://pypi.org/project/Flask-Migrate/
+"
+SRC_URI="
+	https://github.com/miguelgrinberg/Flask-Migrate/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm64 x86"
+
+RDEPEND="
+	>=dev-python/alembic-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.9[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-1.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	local -x PATH=${T}/bin:${PATH}
+
+	mkdir -p "${T}"/bin || die
+	cat > "${T}"/bin/flask <<-EOF || die
+		#!/bin/sh
+		exec ${EPYTHON} -m flask "\${@}"
+	EOF
+	chmod +x "${T}"/bin/flask || die
+
+	eunittest
+}

dev-python/flask-migrate/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">miguelgrinberg/Flask-Migrate</remote-id>
+		<remote-id type="pypi">Flask-Migrate</remote-id>
+	</upstream>
+</pkgmetadata>