[dev-db/timescaledb] bump

dev-db/timescaledb/timescaledb-2.8.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+POSTGRES_COMPAT=( {12..14} )
+POSTGRES_USEDEP="ssl"
+
+inherit cmake postgres-multi
+
+DESCRIPTION="A time-series database optimized for fast ingest and complex queries"
+HOMEPAGE="https://www.timescale.com/"
+SRC_URI="https://github.com/timescale/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0
+	tsl? ( timescale )"
+SLOT="0"
+IUSE="+tsl"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="test"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+src_prepare() {
+	postgres-multi_foreach cmake_src_prepare
+}
+
+src_configure() {
+	pg_src_configure () {
+		local mycmakeargs=(
+			-DAPACHE_ONLY=$(usex tsl OFF ON)
+			-DUSE_OPENSSL=ON
+			-DWARNINGS_AS_ERRORS=OFF
+			-DSEND_TELEMETRY_DEFAULT=OFF
+			-DREGRESS_CHECKS=OFF
+			-DPG_CONFIG=${PG_CONFIG}
+		)
+		cmake_src_configure
+	}
+	postgres-multi_foreach pg_src_configure
+}
+
+src_compile() {
+	postgres-multi_foreach cmake_src_compile
+}
+
+src_install() {
+	postgres-multi_foreach cmake_src_install
+
+	find "${ED}" -name '*.a' -delete
+}