[dev-db/timescaledb] version bump

dev-db/timescaledb/timescaledb-1.6.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+POSTGRES_COMPAT=( 9.6 {10..11} )
+POSTGRES_USEDEP="server,ssl?"
+
+inherit cmake-utils postgres-multi
+
+DESCRIPTION="A time-series database optimized for fast ingest and complex queries"
+HOMEPAGE="https://www.timescale.com/"
+SRC_URI="https://github.com/timescale/${PN}/releases/download/${PV}/${P}.tar.lzma"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="ssl static-libs"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	default
+
+	postgres-multi_src_prepare
+	postgres-multi_foreach cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_OPENSSL=$(usex ssl ON OFF)
+		-DSEND_TELEMETRY_DEFAULT=OFF
+		-DREGRESS_CHECKS=OFF
+	)
+	postgres-multi_foreach cmake-utils_src_configure
+}
+
+src_compile() {
+	postgres-multi_foreach cmake-utils_src_compile
+}
+
+src_install() {
+	postgres-multi_foreach cmake-utils_src_install
+
+	use static-libs || find "${ED}" -name '*.a' -delete
+}