[dev-java/slf4j-*] bump

dev-java/slf4j-log4j12/slf4j-log4j12-1.7.30.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Simple Logging Facade for Java (SLF4J) log4j bindings"
+HOMEPAGE="http://www.slf4j.org/"
+SRC_URI="https://github.com/qos-ch/slf4j/archive/v_${PV}.tar.gz -> ${P/-log4j12/}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-java/log4j:0
+	dev-java/slf4j-api:0"
+
+RDEPEND="${COMMON_DEPEND}
+	>=virtual/jre-1.8"
+DEPEND="${COMMON_DEPEND}
+	>=virtual/jdk-1.8
+	test? (
+		dev-java/hamcrest-core:0
+		dev-java/junit:4
+		dev-java/ant-junit4:0
+	)"
+
+S="${WORKDIR}/${PN/-log4j12/}-v_${PV}/${PN}"
+
+EANT_GENTOO_CLASSPATH="log4j,slf4j-api"
+EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},hamcrest-core,junit-4"
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_EXTRA_ARGS="-Dmaven.build.finalName=${PN}"
+
+src_prepare() {
+	cp "${FILESDIR}"/${PV}-build.xml build.xml || die
+	java-pkg-2_src_prepare
+}
+
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_dojar target/${PN}.jar
+	use doc && java-pkg_dojavadoc target/site/apidocs
+	use source && java-pkg_dosrc src/main/java/org
+}