diff --git a/app-misc/solaar/Manifest b/app-misc/solaar/Manifest
new file mode 100644
index 0000000..f37d212
--- /dev/null
+++ b/app-misc/solaar/Manifest
@@ -0,0 +1 @@
+DIST solaar-1.1.13.tar.gz 1779788 BLAKE2B fd138c3c9faa467e356240e8cfc73f420776228f407092cc2f8bca3a9443e4820dad923c8d997d41934fbf7fd728b17a9674c7f9affaf4cd8616c779f6141ff1 SHA512 4557c82bddf88a604e9316806b8d37296acc4b4486a64605199f85949f6b5d5fd5dd94b25742e5b41d01fba4da40dd5ab2e354d536856ecf3310557b4a7d23a0
diff --git a/app-misc/solaar/metadata.xml b/app-misc/solaar/metadata.xml
new file mode 100644
index 0000000..2605f70
--- /dev/null
+++ b/app-misc/solaar/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>robbat2@gentoo.org</email>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">pwr/Solaar</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/app-misc/solaar/solaar-1.1.13.ebuild b/app-misc/solaar/solaar-1.1.13.ebuild
new file mode 100644
index 0000000..e301a65
--- /dev/null
+++ b/app-misc/solaar/solaar-1.1.13.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit linux-info udev xdg distutils-r1
+
+DESCRIPTION="Linux Device Manager for Logitech Unifying Receivers and Paired Devices"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+if [[ ${PV} =~ 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwr-Solaar/Solaar"
+else
+	SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV/_rc/rc}.tar.gz -> ${P/_rc/rc}.tar.gz"
+	KEYWORDS="amd64 ~arm ~arm64 x86"
+	S="${WORKDIR}"/Solaar-${PV/_rc/rc}
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc appindicator libnotify"
+
+RDEPEND="
+	acct-group/plugdev
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/evdev[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-xlib[${PYTHON_USEDEP}]
+		>=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+
+	')
+	x11-libs/gtk+:3[introspection]
+	appindicator? ( dev-libs/libayatana-appindicator )
+	libnotify? ( x11-libs/libnotify[introspection] )"
+# libayatana-appindicator & libnotify are entirely optional and detected at runtime
+
+BDEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i \
+		-e '/yield autostart_path/d' \
+		setup.py || die
+
+	sed -i -r \
+		-e '/yield.*udev.*rules.d/{s,/etc,/lib,g}' \
+		setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	dodoc docs/devices.md ChangeLog.md
+	if use doc; then
+		dodoc -r docs/*
+	else
+		newdoc docs/index.md README.md
+	fi
+	udev_dorules "${S}"/rules.d/42-logitech-unify-permissions.rules
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	udev_reload
+	xdg_pkg_postrm
+}
diff --git a/app-misc/solaar/solaar-9999.ebuild b/app-misc/solaar/solaar-9999.ebuild
new file mode 100644
index 0000000..9e91df8
--- /dev/null
+++ b/app-misc/solaar/solaar-9999.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit linux-info udev xdg distutils-r1
+
+DESCRIPTION="Linux Device Manager for Logitech Unifying Receivers and Paired Devices"
+HOMEPAGE="https://pwr-solaar.github.io/Solaar/"
+if [[ ${PV} =~ 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/pwr-Solaar/Solaar"
+else
+	SRC_URI="https://github.com/pwr-Solaar/Solaar/archive/${PV/_rc/rc}.tar.gz -> ${P/_rc/rc}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S="${WORKDIR}"/Solaar-${PV/_rc/rc}
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc appindicator libnotify"
+
+RDEPEND="
+	acct-group/plugdev
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/evdev[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-xlib[${PYTHON_USEDEP}]
+		>=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+
+	')
+	x11-libs/gtk+:3[introspection]
+	appindicator? ( dev-libs/libayatana-appindicator )
+	libnotify? ( x11-libs/libnotify[introspection] )"
+# libayatana-appindicator & libnotify are entirely optional and detected at runtime
+
+BDEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i \
+		-e '/yield autostart_path/d' \
+		setup.py || die
+
+	sed -i -r \
+		-e '/yield.*udev.*rules.d/{s,/etc,/lib,g}' \
+		setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	dodoc docs/devices.md ChangeLog.md
+	if use doc; then
+		dodoc -r docs/*
+	else
+		newdoc docs/index.md README.md
+	fi
+	udev_dorules "${S}"/rules.d/42-logitech-unify-permissions.rules
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	udev_reload
+	xdg_pkg_postrm
+}