[dev-db/timescaledb] bump to 2.0.0, update license, moved old one to 1.7 suffix

dev-db/timescaledb/Manifest

@@ -1 +1,2 @@
 DIST timescaledb-1.7.4.tar.lzma 854510 BLAKE2B 40094155c225faf20ddeacd064b698f7546f8c01e07fddbd4af7741d7b808540b5e45a0c644ed380f2b3aae674551132785c7b077eb54eb8b24de271e433cf77 SHA512 81be267b0f87a3cd501962dcf5a9f2ca218b4c4ebd4187d8de600fafc42111742b538bbfaf17bb58153683e98300bfc025f980c19f8d2f9c0ba401df1be5988e
+DIST timescaledb-2.0.0.tar.lzma 1114444 BLAKE2B 117fdb655b5c1eba055b27646c5bdb2f8e7a0dbecbc4f62489927362815ab05d890181d247f322b3cba3a77f4a26cefc525e6068dfe51e07a11b058c2a61412c SHA512 dbeecee126bfa241ae8d5d9c78db2b83c926a62336be4ffc29dfee36bcb4b64db9d59da1f6795a84be537206279fb6df5b51d1612ebfc2d94e538a5da598d40b

dev-db/timescaledb/timescaledb-1.7.4.ebuild

@@ -13,7 +13,7 @@ HOMEPAGE="https://www.timescale.com/"
 SRC_URI="https://github.com/timescale/${PN}/releases/download/${PV}/${P}.tar.lzma"
 
 LICENSE="Apache-2.0
-	tsl? ( TIMESCALE )"
+	tsl? ( TIMESCALE-1.7 )"
 SLOT="0"
 IUSE="ssl +tsl static-libs"
 KEYWORDS="~amd64 ~x86"

dev-db/timescaledb/timescaledb-2.0.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+POSTGRES_COMPAT=( 11..12 )
+POSTGRES_USEDEP="server,ssl?"
+
+inherit cmake postgres-multi
+
+DESCRIPTION="A time-series database optimized for fast ingest and complex queries"
+HOMEPAGE="https://www.timescale.com/"
+SRC_URI="https://github.com/timescale/${PN}/releases/download/${PV}/${P}.tar.lzma"
+
+LICENSE="Apache-2.0
+	tsl? ( TIMESCALE )"
+SLOT="0"
+IUSE="ssl +tsl"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	postgres-multi_foreach cmake_src_prepare
+}
+
+src_configure() {
+	pg_src_configure () {
+		local mycmakeargs=(
+			-DUSE_OPENSSL=$(usex ssl ON OFF)
+			-DAPACHE_ONLY=$(usex tsl OFF ON)
+			-DWARNINGS_AS_ERRORS=OFF
+			-DSEND_TELEMETRY_DEFAULT=OFF
+			-DREGRESS_CHECKS=OFF
+			-DPG_CONFIG=${PG_CONFIG}
+		)
+		cmake_src_configure
+	}
+	postgres-multi_foreach pg_src_configure
+}
+
+src_compile() {
+	postgres-multi_foreach cmake_src_compile
+}
+
+src_install() {
+	postgres-multi_foreach cmake_src_install
+
+	find "${ED}" -name '*.a' -delete
+}