[dev-libs/intel-compute-runtime] add the latest for legacy branch

2026-10-12 18:08:50 +02:00
parent 1a6d9ed3e1
commit ae561aa494
3 changed files with 123 additions and 0 deletions
@@ -0,0 +1 @@
+DIST intel-compute-runtime-24.35.30872.45.tar.gz 7378667 BLAKE2B 6a7767ac8d5bb8f317a17d83396420657adbca284089413023d80c08c9eed1b426f32aafbe79af6332d9742a195d40d90ad9321ea329883f3333ce55527389ca SHA512 0bff2f9b1370a19eb233cedad1337dbd9972214bd85af86f5b66e82c86e4c179f043b9ebfdfb31a67d54545ffa9b54e4c1da5d2fb1868abc0033215507659178
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="legacy/1.5.30872"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND="
+	!dev-libs/intel-compute-runtime:0
+	!dev-util/intel-graphics-compiler:0
+	>=media-libs/gmmlib-22.5.2:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.182:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2=
+	>=dev-util/intel-graphics-system-controller-0.9.5:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.19.2:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+	dev-util/intel-graphics-compiler-bin:legacy
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_ALLOW_LEGACY_PLATFORMS_SUPPORT="ON"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}
@@ -0,0 +1,36 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>gentoo@taujhe.de</email>
+		<name>Jan Henke</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
+		The Intel Graphics Compute Runtime for for oneAPI Level Zero and
+		OpenCL Driver, informally known as NEO, is an open source project providing
+		compute API support (Level Zero, OpenCL) for Intel graphics hardware
+		architectures (HD Graphics, Xe).
+		For OpenCL, NEO supports Intel Core processors with Gen8 graphics devices
+		(Broadwell architecture) and newer, as well as Intel Atom processors with Gen9
+		graphics devices (Apollo Lake, Gemini Lake).
+		Level Zero support is more limited and as of April 2020 still in early stages,
+		please consult upstream release notices for details.
+	</longdescription>
+	<use>
+		<flag name="disable-mitigations">This will disable spectre mitigation, which can speed up the performance.</flag>
+		<flag name="l0">Install the oneAPI Level Zero driver alongside the OpenCL one</flag>
+		<flag name="level-zero">Install the oneAPI Level Zero driver alongside the OpenCL one</flag>
+		<flag name="vaapi">Support the sharing of surfaces with Video Acceleration API (OpenCL Extension #36)</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">intel/compute-runtime</remote-id>
+	</upstream>
+</pkgmetadata>
				`@@ -0,0 +1 @@`
				`DIST intel-compute-runtime-24.35.30872.45.tar.gz 7378667 BLAKE2B 6a7767ac8d5bb8f317a17d83396420657adbca284089413023d80c08c9eed1b426f32aafbe79af6332d9742a195d40d90ad9321ea329883f3333ce55527389ca SHA512 0bff2f9b1370a19eb233cedad1337dbd9972214bd85af86f5b66e82c86e4c179f043b9ebfdfb31a67d54545ffa9b54e4c1da5d2fb1868abc0033215507659178`