[net-im/spectrum] add currently untested release ebuild

net-im/spectrum/Manifest

@@ -0,0 +1 @@
+DIST spectrum-2.0.3.tar.gz 2630522 SHA256 694172dfbf62d7de19bbcc06ba11113d238c86e36d39297b2f80d4b277e03933 SHA512 cc3f26ec12c04b71693375b449beb8a9d4b73d6566c84f24d3cb27590edaf2a8f5924590673a1c46094326f6b4ae34a8fd8beee34982d848fb340339566a0528 WHIRLPOOL dfe8bf6b072cb1964d8ced75cbd219dd634b738716e4fe1f9bbb4809fb497d2fc3e7c89cf871dceef50925aee9a1ba1cd33f83c0595624e5439858e01ac2f7f5

net-im/spectrum/spectrum-2.0.3.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit cmake-utils systemd versionator
+
+MY_PN="spectrum2"
+
+if [[ ${PV} = "9999" ]] ; then
+	EGIT_REPO_URI="git://github.com/hanzz/${MY_PN}.git"
+	inherit git-r3
+	KEYWORDS=""
+else
+	RESTRICT="mirror"
+	MY_PV=$(replace_version_separator '_' '-')
+	MY_P="${MY_PN}-${MY_PV}"
+	SRC_URI="https://github.com/hanzz/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Spectrum is a XMPP transport/gateway"
+HOMEPAGE="http://spectrum.im"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE_PLUGINS="frotz irc jabber purple sms twitter"
+IUSE="debug doc libev mysql postgres sqlite test ${IUSE_PLUGINS}"
+
+RDEPEND="${RDEPEND}
+	>=net-im/swift-3.0
+	dev-libs/boost:=
+	dev-libs/log4cxx
+	dev-libs/openssl
+	dev-libs/popt
+	dev-libs/protobuf
+	mysql? ( virtual/mysql )
+	postgres? ( dev-libs/libpqxx )
+	sqlite? ( dev-db/sqlite:3 )
+	irc? ( net-im/communi )
+	purple? ( >=net-im/pidgin-2.6.0 )
+	libev? ( dev-libs/libev )
+	"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+	"
+
+REQUIRED_USE="|| ( sqlite mysql postgres )"
+
+CMAKE_IN_SOURCE_BUILD=1
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package libev event)
+		-DENABLE_MYSQL="$(usex mysql)"
+		-DENABLE_PQXX="$(usex postgres)"
+		-DENABLE_SQLITE3="$(usex sqlite)"
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_FROTZ="$(usex frotz)"
+		-DENABLE_IRC="$(usex irc)"
+		-DENABLE_SWIFTEN="$(usex jabber)"
+		-DENABLE_PURPLE="$(usex purple)"
+		-DENABLE_SMSTOOLS3="$(usex sms)"
+		-DENABLE_TWITTER="$(usex twitter)"
+		-DLIB_INSTALL_DIR=$(get_libdir)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newinitd "${FILESDIR}"/spectrum2.initd spectrum2
+	systemd_dotmpfilesd "${FILESDIR}"/systemd/spectrum2.conf
+	keepdir "${EPREFIX}"/var/lib/spectrum2
+	keepdir "${EPREFIX}"/var/log/spectrum2
+}
+
+pkg_postinst() {
+	chown jabber:jabber -R "/etc/spectrum2" || die
+	chown jabber:jabber -R "${EPREFIX}/var/lib/spectrum2" || die
+	chown jabber:jabber -R "${EPREFIX}/var/log/spectrum2" || die
+	chmod 750 "/etc/spectrum2" || die
+	chmod 750 "${EPREFIX}/var/lib/spectrum2" || die
+	chmod 750 "${EPREFIX}/var/log/spectrum2" || die
+}

net-im/spectrum/spectrum-9999.ebuild

@@ -16,7 +16,7 @@ else
 	RESTRICT="mirror"
 	MY_PV=$(replace_version_separator '_' '-')
 	MY_P="${MY_PN}-${MY_PV}"
-	SRC_URI="https://github.com/downloads/hanzz/${MY_PN}/${MY_P}.tar.gz"
+	SRC_URI="https://github.com/hanzz/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 	S="${WORKDIR}/${MY_P}"
 	KEYWORDS="~amd64 ~x86"
 fi