From e57bdae7676f9243d4efaec28c651401aa059a30 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Robert=20F=C3=B6rster?= <Dessa@gmake.de>
Date: Mon, 22 Sep 2025 21:41:28 +0200
Subject: [PATCH] [dev-util/include-what-you-use] py3k14 and LLVM 21

---
 dev-util/include-what-you-use/Manifest        |  1 +
 .../include-what-you-use-0.24.ebuild          |  2 +-
 .../include-what-you-use-0.25.ebuild          | 63 +++++++++++++++++++
 3 files changed, 65 insertions(+), 1 deletion(-)
 create mode 100644 dev-util/include-what-you-use/include-what-you-use-0.25.ebuild

diff --git a/dev-util/include-what-you-use/Manifest b/dev-util/include-what-you-use/Manifest
index 43fee0e..6e5286e 100644
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1 +1,2 @@
 DIST include-what-you-use-0.24.tar.gz 821159 BLAKE2B 191d0299c0b5ad6ed75cb24b5530fe606dc6a9ddb91b8d1667ba6f5b909498354b7565e0ebafbfd56eb6e1c4e1c1cf885a0d08b8584d33fae34c4dcbde92ff65 SHA512 62d26a0e646cb6d94d5dee8d672009b938fdcfe64c5c6086693295e90d858754d9a6706b063ddc2cfe5660181df2722a4becfb56285b8cfc6d60f88f729924b7
+DIST include-what-you-use-0.25.tar.gz 847859 BLAKE2B 845525d948d323f1364ec33ff4e6bf55911d74727a297fa008d929fb3af06f290cf1da64e07ad29ef5a661ef8656a4afde5d4c487d89591cca28eb57c1983b49 SHA512 80bdde7edc7f9576eb7ddb36ce0f3dbdc918c46d2bb45362a8583353821275fa6e8058ff091b91c2417e749995d60d6cd1744fcb73b52cbe13829e4c1a0de637
diff --git a/dev-util/include-what-you-use/include-what-you-use-0.24.ebuild b/dev-util/include-what-you-use/include-what-you-use-0.24.ebuild
index 68493e8..51897d5 100644
--- a/dev-util/include-what-you-use/include-what-you-use-0.24.ebuild
+++ b/dev-util/include-what-you-use/include-what-you-use-0.24.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{11..14} )
 LLVM_COMPAT=( 20 )
 
 inherit cmake llvm-r1 python-single-r1
diff --git a/dev-util/include-what-you-use/include-what-you-use-0.25.ebuild b/dev-util/include-what-you-use/include-what-you-use-0.25.ebuild
new file mode 100644
index 0000000..a217aa4
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-0.25.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+LLVM_COMPAT=( 21 )
+
+inherit cmake llvm-r1 python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}=
+		llvm-core/llvm:${LLVM_SLOT}=
+	')
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_setup() {
+	llvm-r1_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix)"
+		# Relative path to the clang library
+		# https://github.com/include-what-you-use/include-what-you-use/commit/e046d23571876e72719ef96a36ff0cb1cb2e64b6
+		-DIWYU_RESOURCE_DIR="../../../clang/${LLVM_SLOT}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py \
+				 -- "${BUILD_DIR}"/bin/${PN} \
+		|| die "Tests failed with $? (using ${EPYTHON})"
+}