[dev-libs/libmongocrypt] bump

dev-libs/libmongocrypt/libmongocrypt-1.15.0.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake dot-a
+
+DESCRIPTION="C library for Client Side and Queryable Encryption in MongoDB"
+HOMEPAGE="https://github.com/mongodb/libmongocrypt"
+SRC_URI="https://github.com/mongodb/libmongocrypt/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~riscv ~x86"
+IUSE="static-libs test"
+REQUIRED_USE="test? ( static-libs )"
+
+RDEPEND="
+	>=dev-libs/libbson-1.30.3[static-libs?]
+	dev-libs/openssl:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/libbson[static-libs]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.11.0-static.patch"
+)
+
+src_configure() {
+	use static-libs && lto-guarantee-fat
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DUSE_SHARED_LIBBSON=ON
+		-DMONGOCRYPT_MONGOC_DIR=USE-SYSTEM
+		-DENABLE_ONLINE_TESTS=OFF
+		-DBUILD_VERSION=${PV}
+		-DENABLE_STATIC="$(usex static-libs ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	strip-lto-bytecode
+}