From f64a9893906c7d5ee883b590fbcb772ad9e26992 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Robert=20F=C3=B6rster?= <Dessa@gmake.de>
Date: Sun, 28 Jun 2026 19:24:08 +0200
Subject: [PATCH] [dev-db/timescaledb] bump

---
 dev-db/timescaledb/Manifest                  |  1 +
 dev-db/timescaledb/timescaledb-2.26.4.ebuild |  4 +-
 dev-db/timescaledb/timescaledb-2.27.2.ebuild | 70 ++++++++++++++++++++
 3 files changed, 73 insertions(+), 2 deletions(-)
 create mode 100644 dev-db/timescaledb/timescaledb-2.27.2.ebuild

diff --git a/dev-db/timescaledb/Manifest b/dev-db/timescaledb/Manifest
index 6d9fd96..b9b5526 100644
--- a/dev-db/timescaledb/Manifest
+++ b/dev-db/timescaledb/Manifest
@@ -1 +1,2 @@
 DIST timescaledb-2.26.4.tar.gz 8503337 BLAKE2B 23b327c47aa85151d72cca09c7f23b225209ef3911d41e4841ab47f3870faf053dbf36094e2269d0f3dd2445a2e489cfc8f255115d6623d288e02c4efce6ecdc SHA512 d4cd5d9ec501e47c24aae53874610559f5e0b04d1008d936d837c635ba2d8b4b1ab277ac0e04756a3ec77b6f1ca039fe1a7ece18038398b4fcc692c7dc920dda
+DIST timescaledb-2.27.2.tar.gz 8672918 BLAKE2B 1bf802ab407dd216d0f9f4ace4ed5a6c7cb0e0e798e0b46af4d4cc788ece224d54feb1994f9477c66b06c7730079beb768df6195e5810500f7077aeb5ea61f2f SHA512 1eda64bbe2aabd4d29c5ef140e3b80bf63e4d9bdcd174814c9674ffc5a79d2307cfdd7d6d1438941519779e291265e2b0ba9618ae0436794021d404eaecfca4e
diff --git a/dev-db/timescaledb/timescaledb-2.26.4.ebuild b/dev-db/timescaledb/timescaledb-2.26.4.ebuild
index 9a91041..32f31f5 100644
--- a/dev-db/timescaledb/timescaledb-2.26.4.ebuild
+++ b/dev-db/timescaledb/timescaledb-2.26.4.ebuild
@@ -14,10 +14,10 @@ SRC_URI="https://github.com/timescale/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="Apache-2.0
 	tsl? ( timescale )"
-SLOT=0
+SLOT="0"
 KEYWORDS="~amd64"
 IUSE="+tsl"
-
+REQUIRED_USE="${POSTGRES_REQ_USE}"
 RESTRICT="test"
 
 DEPEND="${POSTGRES_DEP}"
diff --git a/dev-db/timescaledb/timescaledb-2.27.2.ebuild b/dev-db/timescaledb/timescaledb-2.27.2.ebuild
new file mode 100644
index 0000000..32f31f5
--- /dev/null
+++ b/dev-db/timescaledb/timescaledb-2.27.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+POSTGRES_COMPAT=( {15..18} )
+POSTGRES_USEDEP="ssl"
+
+inherit postgres-multi cmake
+
+DESCRIPTION="Open-source time-series SQL database"
+HOMEPAGE="https://www.timescale.com/"
+SRC_URI="https://github.com/timescale/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0
+	tsl? ( timescale )"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+tsl"
+REQUIRED_USE="${POSTGRES_REQ_USE}"
+RESTRICT="test"
+
+DEPEND="${POSTGRES_DEP}"
+RDEPEND="${DEPEND}"
+
+timescale_src_prepare() {
+	local CMAKE_USE_DIR=$BUILD_DIR
+	cmake_src_prepare
+}
+
+src_prepare() {
+	postgres-multi_src_prepare
+	postgres-multi_foreach timescale_src_prepare
+}
+
+timescale_configure() {
+	local CMAKE_USE_DIR=$BUILD_DIR
+	local mycmakeargs=(
+		-DAPACHE_ONLY=$(usex tsl OFF ON)
+		-DWARNINGS_AS_ERRORS=OFF
+		-DSEND_TELEMETRY_DEFAULT=OFF
+		-DREGRESS_CHECKS=OFF
+		-DPG_CONFIG=${PG_CONFIG}
+	)
+	cmake_src_configure
+}
+
+src_configure() {
+	postgres-multi_foreach timescale_configure
+}
+
+timescale_src_compile() {
+	local CMAKE_USE_DIR=$BUILD_DIR
+	cmake_src_compile
+}
+
+src_compile() {
+	postgres-multi_foreach timescale_src_compile
+}
+
+timescale_src_install() {
+	local CMAKE_USE_DIR=$BUILD_DIR
+	cmake_src_install
+}
+
+src_install() {
+	postgres-multi_foreach timescale_src_install
+
+	find "${ED}" -name '*.a' -delete
+}