# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

POSTGRES_COMPAT=( {14..17} )
POSTGRES_USEDEP="ssl"

inherit cmake postgres-multi

DESCRIPTION="Open-source time-series SQL database"
HOMEPAGE="https://www.timescale.com/"
SRC_URI="https://github.com/timescale/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="Apache-2.0
	tsl? ( timescale )"
SLOT="0"
IUSE="+tsl"
KEYWORDS="~amd64 ~x86"
RESTRICT="test"

DEPEND="${POSTGRES_DEP}"
RDEPEND="${DEPEND}"

timescale_src_prepare() {
	local CMAKE_USE_DIR=$BUILD_DIR
	cmake_src_prepare
}

src_prepare() {
	postgres-multi_src_prepare
	postgres-multi_foreach timescale_src_prepare
}

timescale_src_configure() {
	local CMAKE_USE_DIR=$BUILD_DIR
	local mycmakeargs=(
		-DAPACHE_ONLY=$(usex tsl OFF ON)
		-DWARNINGS_AS_ERRORS=OFF
		-DSEND_TELEMETRY_DEFAULT=OFF
		-DREGRESS_CHECKS=OFF
		-DPG_CONFIG=${PG_CONFIG}
	)
	cmake_src_configure
}

src_configure() {
	postgres-multi_foreach timescale_src_configure
}

timescale_src_compile() {
	local CMAKE_USE_DIR=$BUILD_DIR
	cmake_src_compile
}

src_compile() {
	postgres-multi_foreach timescale_src_compile
}

timescale_src_install() {
	local CMAKE_USE_DIR=$BUILD_DIR
	cmake_src_install
}

src_install() {
	postgres-multi_foreach timescale_src_install

	find "${ED}" -name '*.a' -delete
}