# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

DESCRIPTION="Simple Logging Facade for Java"
HOMEPAGE="http://www.slf4j.org/"
SRC_URI="http://www.slf4j.org/dist/${P/-nop/}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE=""

CDEPEND="dev-java/slf4j-api:0"
RDEPEND=">=virtual/jre-1.8
	${CDEPEND}"
DEPEND=">=virtual/jdk-1.8
	app-arch/unzip
	test? (
		dev-java/ant-junit:0
		dev-java/junit:4
	)
	${CDEPEND}"

S="${WORKDIR}/${P/-nop/}/${PN}"

JAVA_ANT_REWRITE_CLASSPATH="yes"
EANT_GENTOO_CLASSPATH="slf4j-api"
EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit-4"
EANT_TEST_ANT_TASKS="ant-junit"
EANT_EXTRA_ARGS="-Dmaven.build.finalName=${PN}"

src_prepare() {
	cp -v "${FILESDIR}"/${PV}-build.xml "${S}"/build.xml || die
	find "${S}" -name "*.jar" -delete || die
	java-pkg-2_src_prepare
}

src_install() {
	java-pkg_dojar "${S}"/target/${PN}.jar

	use doc && java-pkg_dojavadoc "${S}"/target/site/apidocs
	use source && java-pkg_dosrc "${S}"/src/main/java/org
}

src_test() {
	java-pkg-2_src_test
}