# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

POSTGRES_COMPAT=( 11..12 )
POSTGRES_USEDEP="server,ssl?"

inherit cmake postgres-multi

DESCRIPTION="A time-series database optimized for fast ingest and complex queries"
HOMEPAGE="https://www.timescale.com/"
SRC_URI="https://github.com/timescale/${PN}/releases/download/${PV}/${P}.tar.lzma"

LICENSE="Apache-2.0
	tsl? ( TIMESCALE )"
SLOT="0"
IUSE="ssl +tsl"
KEYWORDS="~amd64 ~x86"

DEPEND="${POSTGRES_DEP}"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

src_prepare() {
	postgres-multi_foreach cmake_src_prepare
}

src_configure() {
	pg_src_configure () {
		local mycmakeargs=(
			-DUSE_OPENSSL=$(usex ssl ON OFF)
			-DAPACHE_ONLY=$(usex tsl OFF ON)
			-DWARNINGS_AS_ERRORS=OFF
			-DSEND_TELEMETRY_DEFAULT=OFF
			-DREGRESS_CHECKS=OFF
			-DPG_CONFIG=${PG_CONFIG}
		)
		cmake_src_configure
	}
	postgres-multi_foreach pg_src_configure
}

src_compile() {
	postgres-multi_foreach cmake_src_compile
}

src_install() {
	postgres-multi_foreach cmake_src_install

	find "${ED}" -name '*.a' -delete
}