# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

inherit cmake java-utils-2 toolchain-funcs

DESCRIPTION="Network Security Services for Java (JSS)"
HOMEPAGE="http://www.dogtagpki.org/wiki/JSS"

SRC_URI="https://github.com/dogtagpki/jss/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MPL-1.1"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~x86"
IUSE="test"

CDEPEND=">=dev-libs/nspr-4.13.1
	>=dev-libs/nss-3.44
	dev-java/commons-lang:2.1
	dev-java/jaxb-api:2
	dev-java/slf4j-api"

DEPEND="${CDEPEND}
	>=virtual/jdk-1.8
	dev-java/junit:4
	test? (
		dev-libs/nss[utils]
	)"

RDEPEND="${CDEPEND}
	>=virtual/jre-1.8
	test? ( dev-java/slf4j-jdk14 )"

src_configure() {
	local mycmakeargs=(
		-DSLF4J_API_JAR=$(java-pkg_getjars slf4j-api)
		-DLANG_JAR=$(java-pkg_getjars commons-lang:2.1)
		-DJAXB_JAR=$(java-pkg_getjars jaxb-api:2)
		-DJUNIT4_JAR=$(java-pkg_getjars junit:4)
	)

	cmake_src_configure
}

src_install() {
	java-pkg_doso "${BUILD_DIR}"/libjss4.so
	java-pkg_dojar "${BUILD_DIR}"/jss4.jar
#	ln -s /usr/share/jss-$(ver_cut 1-2)/lib/jss4.jar "${ED}"/usr/$(get_libdir)/jss-$(ver_cut 1-2)/jss4.jar
}